get-publication-details
Status: 
🔗 References (max. 100)
| part | subject | predicate | object | published by | date | |
|---|---|---|---|---|---|---|
|
Assertion
|
|
|||||
|
Assertion
|
Get publication details
|
|
||||
|
Assertion
|
|
|||||
|
PublicationInfo
|
Get publication details - Given a publication, this query returns its bibliographic details, citing resources, and derived statements as property-value rows.
|
|
||||
|
Assertion
|
Given a publication (identified by its DOI URI or other identifier), this query returns its details as property-value rows: its bibliographic metadata (type, title, authors in list order, journal, date, volume, pages) from the nanopublication introducing it, the resources citing it via CiTO relations (with the citation type in the property label), and the statements (AIDA sentences) that were derived from it. Recognized properties get human-readable labels and are shown first.
|
|
||||
|
Assertion
|
|
|||||
|
Assertion
|
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix bibo: <http://purl.org/ontology/bibo/>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix hycl: <http://purl.org/petapico/o/hycl#>
select ?property ?property_label ?value (min(?vlabel) as ?value_label) where {
{
graph npa:graph { ?np npx:introduces ?_publication_iri ; np:hasAssertion ?a ; npa:hasValidSignatureForPublicKey ?pk . }
filter not exists { graph npa:graph { ?inv npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pk . } }
{
graph ?a { ?_publication_iri ?property ?value . }
filter(?property not in (dct:isPartOf, bibo:authorList, bibo:pageStart, bibo:pageEnd))
bind(if(?property = rdf:type, replace(replace(str(?value), "^.*[/#]", ""), "([a-z])([A-Z])", "$1 $2"), ?xu) as ?vlabel)
bind(
if(?property = rdf:type, "Type",
if(?property = dct:title, "Title",
if(?property = dct:date, "Date",
if(?property = bibo:volume, "Volume",
str(?property))))) as ?property_label)
bind(
if(?property = rdf:type, 0,
if(?property = dct:title, 1,
if(?property = dct:date, 30,
if(?property = bibo:volume, 32,
40)))) as ?sort)
} union {
graph ?a { ?_publication_iri dct:isPartOf ?j . ?j dct:title ?value . }
bind(dct:isPartOf as ?property)
bind("Published in" as ?property_label)
bind(31 as ?sort)
} union {
graph ?a { ?_publication_iri bibo:pageStart ?ps . }
optional { graph ?a { ?_publication_iri bibo:pageEnd ?pe . } }
bind(bibo:pageStart as ?property)
bind("Pages" as ?property_label)
bind(33 as ?sort)
bind(if(bound(?pe) && str(?pe) != str(?ps), concat(str(?ps), "-", str(?pe)), str(?ps)) as ?value)
} union {
graph ?a { ?_publication_iri bibo:authorList ?al . ?al ?m ?author . ?author foaf:name ?value . }
filter(strstarts(str(?m), "http://www.w3.org/1999/02/22-rdf-syntax-ns#_"))
bind(bibo:authorList as ?property)
bind("Author" as ?property_label)
bind(10 + xsd:integer(strafter(str(?m), "#_")) / 1000.0 as ?sort)
}
} union {
graph npa:graph { ?cnp np:hasAssertion ?ca ; npa:hasValidSignatureForPublicKey ?cpk . }
filter not exists { graph npa:graph { ?cinv npx:invalidates ?cnp ; npa:hasValidSignatureForPublicKey ?cpk . } }
graph ?ca { ?value ?property ?_publication_iri . }
filter(strstarts(str(?property), "http://purl.org/spar/cito/"))
bind(concat("Cited by (", lcase(replace(replace(str(?property), "http://purl.org/spar/cito/", ""), "([a-z])([A-Z])", "$1 $2")), ")") as ?property_label)
bind(50 as ?sort)
optional {
graph npa:graph { ?lnp np:hasAssertion ?la ; npa:hasValidSignatureForPublicKey ?lpk . }
filter not exists { graph npa:graph { ?linv npx:invalidates ?lnp ; npa:hasValidSignatureForPublicKey ?lpk . } }
graph ?la { ?value rdfs:label ?vlabel . }
}
} union {
graph npa:graph { ?snp np:hasAssertion ?sa ; npa:hasValidSignatureForPublicKey ?spk . }
filter not exists { graph npa:graph { ?sinv npx:invalidates ?snp ; npa:hasValidSignatureForPublicKey ?spk . } }
graph ?sa {
?value prov:wasDerivedFrom ?_publication_iri .
?value a hycl:AIDA-Sentence .
}
bind(prov:wasDerivedFrom as ?property)
bind("Basis for statement" as ?property_label)
bind(60 as ?sort)
optional { graph npa:graph { ?snp rdfs:label ?vlabel . } }
}
}
group by ?property ?property_label ?value ?sort
order by ?sort str(?value)
|
|
||||
|
PublicationInfo
|
|
|||||
|
Assertion
|
|