get-space-informal-outputs
Status: 
🔗 References (max. 100)
| part | subject | predicate | object | published by | date | |
|---|---|---|---|---|---|---|
|
Assertion
|
|
|||||
|
Assertion
|
Get informal / public-engagement outputs per project for a space and its sub-spaces
|
|
||||
|
Assertion
|
|
|||||
|
Assertion
|
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix gen: <https://w3id.org/kpxl/gen/terms/>
prefix ff: <https://w3id.org/fair/ff/terms/>
prefix prov: <http://www.w3.org/ns/prov#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select ?project ?project_label ?kind ?output ?output_label ?author_label ?np ("^" as ?np_label)
where {
values ?_space_multi_iri {}
service <https://w3id.org/np/l/nanopub-query-1.1/repo/spaces> {
select (group_concat(distinct ?mpk; separator=" ") as ?memberPubkeys) where {
graph npa:graph { <http://purl.org/nanopub/admin/thisRepo> npa:hasCurrentSpaceState ?stateG . }
values ?_space_multi_iri {}
graph ?stateG {
?ri a gen:RoleInstantiation ; npa:forSpace ?_space_multi_iri ; npa:forAgent ?agent ; npa:hasRoleType ?rt .
filter(?rt in (gen:AdminRole, gen:MaintainerRole, gen:MemberRole))
?acct a npa:AccountState ; npa:agent ?agent ; npa:pubkey ?mpk .
}
}
}
graph npa:graph {
?np npa:hasValidSignatureForPublicKeyHash ?npPubkey .
filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKeyHash ?npPubkey . }
filter not exists { ?np npx:hasNanopubType npx:ExampleNanopub . }
?np np:hasAssertion ?a .
?np np:hasPublicationInfo ?pi .
}
filter(contains(?memberPubkeys, ?npPubkey))
graph ?a {
?project ?rel ?output .
values ?rel { ff:has-blog-post ff:has-media-coverage ff:has-social-post ff:has-podcast ff:has-discussion }
optional { ?output rdfs:label ?output_label }
}
filter(?project = ?_space_multi_iri || strstarts(str(?project), concat(str(?_space_multi_iri), "/")))
bind(strafter(str(?rel), "https://w3id.org/fair/ff/terms/has-") as ?kind)
optional { graph ?pi { ?project nt:hasLabelFromApi ?project_label } }
optional {
graph ?a { ?output prov:wasAttributedTo ?author }
graph ?pi { ?author foaf:name ?author_label }
}
}
order by ?project_label ?kind ?output_label
|
|
||||
|
PublicationInfo
|
|
|||||
|
Assertion
|
|